home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Tech Arsenal 1
/
Tech Arsenal (Arsenal Computer).ISO
/
tek-04
/
cams304.zip
/
XCAMS.BAT
< prev
Wrap
DOS Batch File
|
1988-12-09
|
5KB
|
127 lines
ECHO OFF
IF NOT EXIST CAMS.SCR GOTO CLEARIT
TYPE CAMS.SCR
PAUSE >NUL
:CLEARIT
CLS
ECHO ┌─────────────────────────────────────────────────────────────────────┐
ECHO │ C O M P U T E R G E O M E T R Y C O M P A N Y │
ECHO │ │
ECHO │ C A M S │
ECHO ├─────────────────────────────────────────────────────────────────────┤
IF %1T == T GOTO ERROR
IF EXIST CAMS.TBL GOTO NEXT1
COPY C:\CAMS\CAMS.TBL > NUL
:NEXT1
IF NOT EXIST %1.NC GOTO ERROR
IF %2T == T GOTO NOLIST
IF %2T == MT GOTO NOLIST
IF %2T == LT GOTO LIST
IF %2T == PT GOTO NOLIST
IF %2T == LPT GOTO LIST
IF %2T == MLT GOTO LIST
IF %2T == MPT GOTO NOLIST
IF %2T == MLPT GOTO LIST
:ERROR
ECHO │ The correct command for the execution of the CAMS system is: │
ECHO │ │
ECHO │ XCAMS {name} [MLP/ML/MP/LP/M/L/P] [plotter] [machine] │
ECHO │ │
ECHO │ e.g. XCAMS CAMPLATE LP VIDEO │
ECHO │ │
ECHO │ {name} ... The source file name (without extension) - required │
ECHO │ M ... Machine output --- [machine] name is required │
ECHO │ L ... Listing output --- produces {name}.LST │
ECHO │ P ... Plotter output --- [plotter] name is required │
ECHO │ NOTE: ... Options omitting the "L" will print to the screen │
ECHO ├─────────────────────────────────────────────────────────────────────┤
ECHO │ │
ECHO │ Your command ... XCAMS %1 %2 %3 %4
ECHO │ │
IF %1T == T GOTO NONE
IF EXIST %1.NC GOTO ERROR2
ECHO │ The source file is not accessible via the specified path . . . │
GOTO ERROR3
:NONE
ECHO │ You must specify an argument for {name} . . . . . . . . . . . . │
GOTO ERROR3
:ERROR2
ECHO │ The option characters (M,L,P) must be omitted or entered as shown │
:ERROR3
ECHO └─────────────────────────────────────────────────────────────────────┘
GOTO END
:LIST
ECHO │ CAMS processing - please stand-by . . . . . . . . . . . . │
ECHO └─────────────────────────────────────────────────────────────────────┘
ECHO ON
C:\CAMS\CAMS1 %1.NC > %1.LST
C:\CAMS\CAMS2 %1.PRO >> %1.LST
ECHO OFF
IF %2T == LT GOTO DONE
GOTO NEXT2
:NOLIST
ECHO │ CAMS processing - please stand-by . . . . . . . . . . . . │
ECHO └─────────────────────────────────────────────────────────────────────┘
ECHO ON
C:\CAMS\CAMS1 %1.NC
C:\CAMS\CAMS2 %1.PRO
ECHO OFF
IF %2T == T GOTO DONE
:NEXT2
IF %2T == MT GOTO NOPLOT
IF %2T == MLT GOTO NOPLOT
IF EXIST C:\CAMS\%3PP.EXE GOTO PLOT2
ECHO ┌─────────────────────────────────────────────────────────────────────┐
ECHO │ %3 Plotter is not available . . . . .
ECHO └─────────────────────────────────────────────────────────────────────┘
GOTO PLOT3
:PLOT2
C:\CAMS\%3PP %1.CLF
:PLOT3
IF %2T == PT GOTO DONE
IF %2T == LPT GOTO DONE
:NOPLOT
IF %2T == MT GOTO POST3
IF %2T == MLT GOTO POST3
IF EXIST C:\CAMS\%4PP.EXE GOTO POST1
ECHO ┌─────────────────────────────────────────────────────────────────────┐
ECHO │ %4 Postprocessor is not available . .
ECHO └─────────────────────────────────────────────────────────────────────┘
GOTO DONE
:POST1
IF %2T == MLPT GOTO POST1L
ECHO ON
C:\CAMS\%4PP %1.CLF
ECHO OFF
GOTO DONE
:POST1L
ECHO ON
C:\CAMS\%4PP %1.CLF >> %1.LST
ECHO OFF
GOTO DONE
:POST3
IF EXIST C:\CAMS\%3PP.EXE GOTO POST2
ECHO ┌─────────────────────────────────────────────────────────────────────┐
ECHO │ %3 Postprocessor is not available . .
ECHO └─────────────────────────────────────────────────────────────────────┘
GOTO DONE
:POST2
IF %2T == MLT GOTO POST3L
ECHO ON
C:\CAMS\%3PP %1.CLF
ECHO OFF
GOTO DONE
:POST3L
ECHO ON
C:\CAMS\%3PP %1.CLF >> %1.LST
ECHO OFF
:DONE
ECHO ┌─────────────────────────────────────────────────────────────────────┐
ECHO │ CAMS processing completed │
ECHO └─────────────────────────────────────────────────────────────────────┘
:END
IF EXIST %1.CAN ERASE %1.CAN > NUL
IF EXIST %1.PRO ERASE %1.PRO > NUL
IF EXIST %1.CLF ERASE %1.CLF > NUL
ECHO ON